**Prescriber Profiling from a Pharmacy Benefits Management (PBM) Perspective**

The goal of the PBM is to provide the absolute best care in terms of medication for the members while reducing the cost of medication expense borne by the Health Plan and the members. In this way both patient outcomes and Health Care affordability can be maximized and as a result, society benefits.

Typically Physician Profiling Reports are utilized in medical claims benefit management to compare physician services with other peer physicians in similar specialties to monitor various metrics and provide incentives to physicians for cost effective strategies which help lower Benefit Plan costs. Performance Measures are focused more on medical procedures and visits, rather than medication prescribing. However, Prescriber Profiling focused on prescription drugs is also very useful.

In order for Clinical Pharmacists to use the data efficiently to improve patient outcomes and reduce cost, the data must be transformed into actionable information. This paper outlines very specifically utilizing the power of SAS programming Data Step and PROC Step methodology to convert large quantities of data into an organized and meaningful Prescriber Profiling report focused on medication prescribing that can be used to achieve these goals.

Analysis of prescriber metrics compared to the entire Plan metrics is important to this process. Therefore I selected the following eight industry standard metrics to study, at the prescriber level as compared to the average Plan level:

1. Generic Utilization Rate
   1. generic drugs divided by all brand and generic drugs
   2. low generic utilization rates are problematic because brand drugs cost more and are not always more effective
2. Formulary Compliance
   1. drugs on plan formulary divided by formulary plus non-formulary drugs
   2. formulary drugs are deemed more effective and in some cases less costly
3. Brand Cost Per Rx
   1. brand drug cost divided by brand drug prescription count
   2. higher than average brand drug cost per prescription should be researched
4. Generic Cost Per Rx
   1. generic drug cost divided by generic drug prescription count
   2. higher than average generic drug cost per prescription should be researched
5. Specialty Cost Per Rx
   1. specialty drug cost divided by specialty drug prescription count
   2. higher than average specialty drug cost per prescription should be researched
6. Hep C Drug Utilization
   1. percent of Hep C drug claims
   2. higher than average Hep C drug claim percentage should be researched
7. Specialty Drug Utilization
   1. percent of higher cost Specialty Drug claims
   2. higher than average Specialty Drug claim percentage should be researched
8. Opioid Drug Utilization
   1. percent of Opioid drug claims
   2. higher than average Opioid drug claim percentage should be researched

In the recent past, although non-Specialty drug cost trends are somewhat flat or slightly increasing from year to year, higher cost Specialty drug cost trends, especially Hep C treatment drugs have risen materially and it is important to manage these costs while providing the best possible patient care. Given the recent and dangerous epidemic of Opioid overuse, it is imperative to track Opioid use from a member safety standpoint and intervene where necessary.

In order to leverage our resource assets to the maximize advantage, it is important to reduce the vast number of prescriber data reviewed to a manageable amount. Researching every prescriber metric determined to be above average for every Plan would be a momentous and unreasonable exercise. Therefore I came up with an idea, specifically to produce one warning flag per prescriber for each of the above eight metrics where the prescriber is an outlier, accumulate the warning count 1 to 8, and create Tiers of prescribers to review based on this warning count. For example, if one prescriber is an outlier in 8 of the above 8 metrics, they are assigned to Tier 8 and are considered the top risk priority. Prescribers that are an outlier in 7 of 8 metrics go to Tier 7, and so on and so forth. Tier 0, the largest group by far, are prescribers with outliers in 0 out of 8 metrics and are zero risk for this process.

Another important metric is percent spend per prescriber, in other words what percent cost to total spend is attributed to each individual prescriber. For example if there are 10 prescribers in the Tier 8 category, it makes sense to sort in descending percent spend order and review prescribers who impact the total dollar spend the most. If Dr. Smith has 2% of total spend and Dr. Jones has .0045% of total spend, my resources would be better spent to review Dr. Smith’s data rather than Dr. Jones’ data.

The first step in creating this logic is to pull the data from the company Data Warehouse. In order to improve flexibility for running various customers and various date spans, macro variables for customer number, beginning fill date and end fill date are created.

LIBNAME odb ODBC DSN=InformDB user=InformaticsUser pw=P@ssw0rd schema=dbo;

LIBNAME PRESCR "I:\SAS\Projects";

\*\*\* CREATE MACRO VARIABLES \*\*\*;

%let Customer = 603;

%let StartDate = '20180901';

%let EndDate = '20180930';

\*\*\* READ DATA FROM DATA WAREHOUSE TO CREATE PRESCRIBER PROFILING REPORT \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*;

**DATA** PRESCR.PLAN(KEEP = CUSTOMERID CLAIMNO GCN NDC FILLDT PAIDAMT CICSCLAIMSSTATUSCODE CLAIMTYPE

PLANMETQTY PLANDAYSSUPPLY PRESCRIBERID PRESCRIBERLASTNAME DRUGCATEGORYCODE

DRUGNAME SPECIFICTHERAPEUTICCD GI GPI FORMULARYIND MAINTENANCEDRUGIND COMPOUNDCODE

PRESCRIBERIDNPI DME PRESCRIBERSPECIALTY BRANDGENERICCODE GROUPID);

SET ODB.FinalizedFactRxClaims(WHERE=(CUSTOMERID = &Customer. AND &StartDate. <= FILLDT <= &EndDate. ));

**RUN**;

**PROC** **SORT** DATA = PRESCR.PLAN;

BY GCN;

**RUN**;

The next step is to identify specialty drugs paid with the specialty benefit, and update each data record by merging by the drug indicator Generic Code Number (GCN). Note we create a SPECIALTY flag and value with “Y” or “N”.

\*\*\* IDENTIFY DRUGS ADJUDICATED WITH THE SPECIALTY RATE USING PERFORMRX SPECIALTY LIST \*\*\*;

**PROC** **IMPORT** OUT = WORK.SPECIALTY

DATAFILE = "T:\Pharmacy\_Informatics\Informatics\Reference\Specialty and Injectables\

Specialty Formulary - Perform Specialty\_2018-11-06.xlsx"

DBMS=EXCELCS REPLACE;

SHEET = "GCN\_LIST";

**RUN**;

**DATA** PRESCR.SPEC (KEEP = GCN);

SET SPECIALTY;

IF GCN = ' ' THEN DELETE;

**RUN**;

**PROC** **SORT** DATA = PRESCR.SPEC;

BY GCN;

**RUN**;

**DATA** PLAN2 SPECONLY;

MERGE PRESCR.PLAN (IN=A) PRESCR.SPEC (IN=B);

BY GCN;

IF A AND B THEN

DO;

SPECIALTY = "Y";

OUTPUT PLAN2;

END;

ELSE IF A AND NOT B THEN

DO;

SPECIALTY = "N";

OUTPUT PLAN2;

END;

ELSE IF B AND NOT A THEN OUTPUT SPECONLY;

**RUN**;

The next step is to merge to the First Data Bank drug information database by National Drug Code (NDC), another drug identifier, and add some important drug identifiers that will be useful to our Clinicians reviewing the data. Note since all drugs in our claim data should also match the entire population of possible drugs, I have included an ABORT statement to abend the SAS Program if a non-match is encountered. In the event of an ABORT, this would force manual research to ensure validity of results.

\*\*\* MERGE TO FIRST DATA BANK DATABASE TO ADD CRITICAL DRUG IDENTIFICATION FIELDS \*\*\*;

**PROC** **IMPORT** OUT = WORK.FDB (KEEP = NDC BN LN GNN INNOV AHFS8 AHFS\_DESCRIPTION HIC3\_DESC)

DATAFILE = "T:\Pharmacy\_Informatics\Informatics\FDB\FDB\_MEDSP\_CROSSWALK\FDB3YR\_MEDSP\_MSTR\_20181112.xlsx"

DBMS=EXCELCS REPLACE;

SHEET = "FDBMED\_3YRS";

**RUN**;

**PROC** **SORT** DATA = FDB;

BY NDC;

**RUN**;

**PROC** **SORT** DATA = PLAN2;

BY NDC;

**RUN**;

\*\*\* ALL CLAIM RECORDS SHOULD MATCH TO THE FIRST DATA BANK DATABASE \*\*\*;

\*\*\* ABORT PROGRAM FOR RESEARCH PURPOSES IF DRUG RECORDS ARE ENCOUNTERED THAT DO NOT MATCH TO THE FIRST DATABANK DATABASE \*\*\*;

**DATA** PLAN3 FDBONLY;

MERGE PLAN2 (IN=A) FDB (IN=B);

BY NDC;

IF A AND B THEN OUTPUT PLAN3;

ELSE IF A AND NOT B THEN **ABORT**;

ELSE IF B AND NOT A THEN OUTPUT FDBONLY;

**RUN**;

Now we need to identify Opioid drugs and create an OPIOID flag with values “Y” and “N”.

\*\*\* MERGE TO OPIOID DRUG IDENTIFICATION FILE IN ORDER TO IDENTIFY OPIOIDS \*\*\*;

**PROC** **IMPORT** OUT = WORK.OPIOIDS (KEEP = GCN)

DATAFILE = "I:\SAS\Projects\Opioids.xlsx"

DBMS=EXCELCS REPLACE;

SHEET = "OPIOIDS";

**RUN**;

**PROC** **SORT** DATA = OPIOIDS;

BY GCN;

**RUN**;

**PROC** **SORT** DATA = PLAN3;

BY GCN;

**RUN**;

**DATA** PLAN3A OPIOIDSONLY;

MERGE PLAN3 (IN=A) OPIOIDS (IN=B);

BY GCN;

IF A AND B THEN

DO;

OPIOIDS = "Y";

OUTPUT PLAN3A;

END;

ELSE IF A AND NOT B THEN

DO;

OPIOIDS = "N";

OUTPUT PLAN3A;

END;

ELSE IF B AND NOT A THEN OUTPUT OPIOIDSONLY;

**RUN**;

Next we process records, create a SAS date using the MDY function, categorize drugs as brand, generic or supplies, assign Hep C drugs and create a HEPC flag valued “Y” or “N” and start building various drug counts to use as a basis for calculating metrics.

\*\*\* PROCESS RECORDS \*\*\*;

**DATA** PLAN4;

SET PLAN3A;

FORMAT DATE\_FILLED MONYY5.;

BETA=**1**;

\*\*\* CREATE SAS DATE \*\*\*;

MM = SUBSTR(FILLDT,**6**,**2**);

DD = SUBSTR(FILLDT,**9**,**2**);

YY = SUBSTR(FILLDT,**1**,**4**);

DATE\_FILLED = MDY(MM,DD,YY);

RXCOUNT = **1**;

\*\*\* DETERMINE BRAND VERSUS GENERIC DRUGS \*\*\*;

IF GPI = "0" THEN DRUG\_TYPE = "DME SUPPLIES";

ELSE IF GI = "2" AND GPI = "2" THEN DRUG\_TYPE = "BRAND";

ELSE IF GI = '1' AND GPI = '1' THEN DRUG\_TYPE = "GENERIC";

ELSE IF GI = '1' AND GPI = '2' THEN DRUG\_TYPE = "BRAND";

ELSE IF GI = '2' AND GPI = '1' THEN DRUG\_TYPE = "GENERIC";

\*\*\* ASSIGN HEP C DRUGS \*\*\*;

HEPC = 'N';

IF GCN IN ('29964' '29941' '35708' '35648' '37179' '37614' '37073'

'37074' '37844' '40615' '41729' '41335' '41932' '43634' '43699') THEN HEPC = "Y";

\*\*\* SET COUNTS AND AMOUNTS TO ZERO \*\*\*;

FORMULARY\_COUNT = **0**;

NONFORMULARY\_COUNT = **0**;

BRAND\_COUNT = **0**;

BRAND\_AMT = **0**;

GENERIC\_COUNT = **0**;

GENERIC\_AMT = **0**;

HEPC\_COUNT = **0**;

HEPC\_AMT = **0**;

SPECIALTY\_COUNT = **0**;

SPECIALTY\_AMT = **0**;

OPIOID\_COUNT = **0**;

OPIOID\_AMT = **0**;

IF FORMULARYIND = **1** THEN FORMULARY\_COUNT = RXCOUNT;

ELSE IF FORMULARYIND = **2** THEN NONFORMULARY\_COUNT = RXCOUNT;

\*\*\* BRAND DRUGS NOT SPECIALTY \*\*\*;

IF DRUG\_TYPE = "BRAND" AND SPECIALTY = "N" THEN

DO;

BRAND\_COUNT = RXCOUNT;

BRAND\_AMT = PAIDAMT;

END;

\*\*\* GENERIC DRUGS NOT SPECIALTY \*\*\*;

ELSE IF DRUG\_TYPE = "GENERIC" AND SPECIALTY = "N" THEN

DO;

GENERIC\_COUNT = RXCOUNT;

GENERIC\_AMT = PAIDAMT;

END;

\*\*\* HEP C DRUGS \*\*\*;

IF HEPC = "Y" THEN

DO;

HEPC\_COUNT = RXCOUNT;

HEPC\_AMT = PAIDAMT;

END;

\*\*\* SPECIALTY DRUGS \*\*\*;

IF SPECIALTY = "Y" THEN

DO;

SPECIALTY\_COUNT = RXCOUNT;

SPECIALTY\_AMT = PAIDAMT;

END;

\*\*\* OPIOID DRUGS \*\*\*;

IF OPIOIDS ="Y" THEN

DO;

OPIOID\_COUNT = RXCOUNT;

OPIOID\_AMT = PAIDAMT;

END;

**RUN**;

We now need to summarize by prescriber identification number using a PROC SUMMARY procedure.

\*\*\* SUMMARIZE AT PRESCRIBER LEVEL \*\*\*;

**PROC** **SUMMARY** NWAY MISSING DATA = PLAN4;

CLASS PRESCRIBERID;

VAR RXCOUNT PAIDAMT FORMULARY\_COUNT NONFORMULARY\_COUNT BRAND\_COUNT BRAND\_AMT

GENERIC\_COUNT GENERIC\_AMT HEPC\_COUNT HEPC\_AMT SPECIALTY\_COUNT SPECIALTY\_AMT

OPIOID\_COUNT OPIOID\_AMT;

ID PRESCRIBERLASTNAME BETA;

OUTPUT OUT = PLAN4\_SUMMM (DROP = \_TYPE\_ \_FREQ\_)SUM=;

**RUN**;

Next we calculate all prescriber metrics for this project which are Generic Utilization Rate, Formulary Compliance, Percent Hep C, Percent Specialty, Percent Opioid, Brand Cost Per Rx, Generic Cost Per Rx, and Specialty Cost Per Rx.

\*\*\* CALCULATE ALL PRESCRIBER METRICS \*\*\*;

**DATA** PLAN5;

SET PLAN4\_SUMMM;

IF (BRAND\_COUNT + GENERIC\_COUNT) NE **0** THEN GUR = (GENERIC\_COUNT/(BRAND\_COUNT + GENERIC\_COUNT));

ELSE IF (BRAND\_COUNT + GENERIC\_COUNT) = **0** THEN GUR = **0**;

IF (FORMULARY\_COUNT + NONFORMULARY\_COUNT) NE **0**

THEN FORMULARY\_COMPLIANCE = (FORMULARY\_COUNT / (FORMULARY\_COUNT + NONFORMULARY\_COUNT));

ELSE IF (FORMULARY\_COUNT + NONFORMULARY\_COUNT) = **0** THEN FORMULARY\_COMPLIANCE = **0**;

PERCENT\_HEPC = (HEPC\_COUNT / RXCOUNT);

PERCENT\_SPEC = (SPECIALTY\_COUNT / RXCOUNT);

IF BRAND\_COUNT NE **0** THEN BRANDCOST\_RX = (BRAND\_AMT/BRAND\_COUNT);

ELSE IF BRAND\_COUNT = **0** THEN BRANDCOST\_RX = **0**;

IF GENERIC\_COUNT NE **0** THEN GENERICCOST\_RX = (GENERIC\_AMT/GENERIC\_COUNT);

ELSE IF GENERIC\_COUNT = **0** THEN GENERICCOST\_RX = **0**;

IF SPECIALTY\_COUNT NE **0** THEN SPECIALTYCOST\_RX = (SPECIALTY\_AMT/SPECIALTY\_COUNT);

ELSE IF SPECIALTY\_COUNT = **0** THEN SPECIALTYCOST\_RX = **0**;

PERCENT\_OPIOID = (OPIOID\_COUNT / RXCOUNT);

**RUN**;

We now need to summarize at the Plan level, so we can compare Prescriber versus Plan per metric and identify outliers.

\*\*\* SUMMARIZE AT PLAN LEVEL TO MAKE COMPARISONS \*\*\*;

**PROC** **SUMMARY** NWAY MISSING DATA = PLAN4;

CLASS BETA;

VAR RXCOUNT PAIDAMT FORMULARY\_COUNT NONFORMULARY\_COUNT BRAND\_COUNT

BRAND\_AMT GENERIC\_COUNT GENERIC\_AMT HEPC\_COUNT HEPC\_AMT SPECIALTY\_COUNT

SPECIALTY\_AMT OPIOID\_COUNT OPIOID\_AMT;

OUTPUT OUT = PLANTOT4\_SUMMM (DROP = \_TYPE\_ \_FREQ\_)SUM=;

**RUN**;

Next we calculate the metrics at the Plan level.

\*\*\* CALCULATE ALL PLAN METRICS \*\*\*;

**DATA** PLANTOT5 (KEEP = BETA PLANRXCOUNT PLANPAIDAMT PLANFORMULARY\_COUNT PLANNONFORMULARY\_COUNT

PLANBRAND\_COUNT PLANBRAND\_AMT PLANGENERIC\_COUNT PLANGENERIC\_AMT PLANHEPC\_COUNT

PLANHEPC\_AMT PLANSPECIALTY\_COUNT PLANSPECIALTY\_AMT PLANOPIOID\_COUNT

PLANOPIOID\_AMT PLANGUR PLANFORMULARY\_COMPLIANCE PLANPERCENT\_HEPC PLANPERCENT\_SPEC

PLANBRANDCOST\_RX PLANGENERICCOST\_RX PLANSPECIALTYCOST\_RX PLANPERCENT\_OPIOID);

SET PLANTOT4\_SUMMM;

PLANRXCOUNT = RXCOUNT;

PLANPAIDAMT = PAIDAMT;

PLANFORMULARY\_COUNT = FORMULARY\_COUNT;

PLANNONFORMULARY\_COUNT = NONFORMULARY\_COUNT;

PLANBRAND\_COUNT = BRAND\_COUNT;

PLANBRAND\_AMT = BRAND\_AMT;

PLANGENERIC\_COUNT = GENERIC\_COUNT;

PLANGENERIC\_AMT = GENERIC\_AMT;

PLANHEPC\_COUNT = HEPC\_COUNT;

PLANHEPC\_AMT = HEPC\_AMT;

PLANSPECIALTY\_COUNT = SPECIALTY\_COUNT;

PLANSPECIALTY\_AMT=SPECIALTY\_AMT;

PLANGUR = (GENERIC\_COUNT/(BRAND\_COUNT + GENERIC\_COUNT));

PLANFORMULARY\_COMPLIANCE = (FORMULARY\_COUNT / (FORMULARY\_COUNT + NONFORMULARY\_COUNT));

PLANPERCENT\_HEPC = (HEPC\_COUNT / RXCOUNT);

PLANPERCENT\_SPEC = (SPECIALTY\_COUNT / RXCOUNT);

PLANBRANDCOST\_RX = (BRAND\_AMT/BRAND\_COUNT);

PLANGENERICCOST\_RX = (GENERIC\_AMT/GENERIC\_COUNT);

PLANSPECIALTYCOST\_RX = (SPECIALTY\_AMT/SPECIALTY\_COUNT);

PLANOPIOID\_COUNT = OPIOID\_COUNT;

PLANOPIOID\_AMT = OPIOID\_AMT;

PLANPERCENT\_OPIOID = (OPIOID\_COUNT / RXCOUNT);

**RUN**;

Next we merge the prescriber level information and the plan level information together, using a field created called BETA, so each prescriber record will also have the total Plan metrics for comparison purposes. Additionally we create our PercentSpend field, we create our 8 Warning fields, we compare prescriber to Plan at the metric level, we increment our FLAG value based on the number of warnings (1-8) and we create our review Tiers. Note again we ABORT the program if there is no match.

\*\*\* ALL RECORDS SHOULD MERGE OR ABEND AND RESEARCH ERROR \*\*\*;

**DATA** PLAN6;

FORMAT PRESCRIBERID PRESCRIBERLASTNAME $15. RXCOUNT PLANRXCOUNT COMMA8.

PAIDAMT PLANPAIDAMT DOLLAR15.2 FORMULARY\_COUNT PLANFORMULARY\_COUNT

NONFORMULARY\_COUNT PLANNONFORMULARY\_COUNT COMMA8.

FORMULARY\_COMPLIANCE PLANFORMULARY\_COMPLIANCE PERCENT9.2

BRAND\_COUNT PLANBRAND\_COUNT GENERIC\_COUNT PLANGENERIC\_COUNT COMMA8.

GUR PLANGUR PERCENT9.2 BRAND\_AMT PLANBRAND\_AMT

BRANDCOST\_RX PLANBRANDCOST\_RX GENERIC\_AMT PLANGENERIC\_AMT GENERICCOST\_RX

PLANGENERICCOST\_RX SPECIALTY\_AMT PLANSPECIALTY\_AMT SPECIALTYCOST\_RX

PLANSPECIALTYCOST\_RX DOLLAR15.2 SPECIALTY\_COUNT PLANSPECIALTY\_COUNT COMMA8.

PERCENT\_SPEC PLANPERCENT\_SPEC PERCENT9.2 HEPC\_COUNT PLANHEPC\_COUNT COMMA8.

PERCENT\_HEPC PLANPERCENT\_HEPC PERCENT9.2 HEPC\_AMT PLANHEPC\_AMT DOLLAR15.2

OPIOID\_COUNT PLANOPIOID\_COUNT COMMA8. OPIOID\_AMT PLANOPIOID\_AMT DOLLAR15.2

PERCENT\_OPIOID PLANPERCENT\_OPIOID PERCENTSPEND PERCENT9.2

WARNING1 WARNING2 WARNING3 WARNING4 WARNING5 WARNING6 WARNING7 WARNING8 $60. BETA **1.**;

MERGE PLAN5 (IN=A) PLANTOT5 (IN=B);

BY BETA;

IF A AND B THEN

DO;

PERCENTSPEND = (PAIDAMT/PLANPAIDAMT);

\*\*\* DEVELOP WARNINGS FOR OUTLIER PRESCRIBER UTILIZATION/COST \*\*\*;

WARNING1 = ' ';

WARNING2 = ' ';

WARNING3 = ' ';

WARNING4 = ' ';

WARNING5 = ' ';

WARNING6 = ' ';

WARNING7 = ' ';

WARNING8 = ' ';

\*\*\* SET FLAG MECHANISM TO ZERO \*\*\*;

FLAG = **0**;

\*\*\* INCREMENT FLAG BASED ON NUMBER OF WARNINGS \*\*\*;

IF GUR < PLANGUR THEN

DO;

FLAG + **1**;

WARNING1 = "Prescriber Generic Utilization Rate Lower Than Plan Average";

END;

IF FORMULARY\_COMPLIANCE < PLANFORMULARY\_COMPLIANCE THEN

DO;

FLAG + **1**;

WARNING2 = "Prescriber Formulary Compliance Lower Than Plan Average";

END;

IF BRANDCOST\_RX > PLANBRANDCOST\_RX THEN

DO;

FLAG + **1**;

WARNING3 = "Prescriber Brand Cost Per Rx Higher Than Plan Average";

END;

IF GENERICCOST\_RX > PLANGENERICCOST\_RX THEN

DO;

FLAG + **1**;

WARNING4 = "Prescriber Generic Cost Per Rx Higher Than Plan Average";

END;

IF SPECIALTYCOST\_RX > PLANSPECIALTYCOST\_RX THEN

DO;

FLAG + **1**;

WARNING5 = "Prescriber Specialty Cost Per Rx Higher Than Plan Average";

END;

IF PERCENT\_HEPC > PLANPERCENT\_HEPC THEN

DO;

FLAG + **1**;

WARNING6 = "Prescriber Hep C Drug Utilization Higher Than Plan Average";

END;

IF PERCENT\_SPEC > PLANPERCENT\_SPEC THEN

DO;

FLAG + **1**;

WARNING7 = "Prescriber Specialty Utilization Higher Than Plan Average";

END;

IF PERCENT\_OPIOID > PLANPERCENT\_OPIOID THEN

DO;

FLAG + **1**;

WARNING8 = "Prescriber Opioid Utilization Higher Than Plan Average";

END;

\*\*\* CREATE TIERS BASED ON NUMBER OF FLAGS FOR CLINICAL STAFF TO REVIEW TOP TIERS AND LOOK FOR \*\*\*;

\*\*\* OPPORTUNITIES TO IMPROVE PATIENT CARE/SAFETY AND DECREASE COST \*\*\*;

TIER = **0**;

IF FLAG = **8** THEN TIER = **8**;

ELSE IF FLAG = **7** THEN TIER = **7**;

ELSE IF FLAG = **6** THEN TIER = **6**;

ELSE IF FLAG = **5** THEN TIER = **5**;

ELSE IF FLAG = **4** THEN TIER = **4**;

ELSE IF FLAG = **3** THEN TIER = **3**;

ELSE IF FLAG = **2** THEN TIER = **2**;

ELSE IF FLAG = **1** THEN TIER = **1**;

ELSE TIER = **0**;

OUTPUT PLAN6;

END;

\*\*\* ALL RECORDS MUST MERGE THEREFORE ABORT IF RECORDS DO NOT MERGE \*\*\*;

ELSE IF A AND NOT B THEN ABORT;

ELSE IF B AND NOT A THEN ABORT;

**RUN**;

Next we create two data sets for each Tier, one with metrics and one with all corresponding fields. In order to create field descriptive titles for output to MS Excel, we create LABELS. The other alternative of editing the MS Excel file tabs is very time consuming and inefficient.

\*\*\* CREATE TWO DATA SETS PER TIER, ONE STREAMLINED AND ONE WITH ALL CORRESPONDING DETAIL \*\*\*;

**DATA** TIER0 (KEEP = PRESCRIBERID PRESCRIBERLASTNAME PERCENTSPEND GUR PLANGUR

FORMULARY\_COMPLIANCE PLANFORMULARY\_COMPLIANCE BRANDCOST\_RX

PLANBRANDCOST\_RX GENERICCOST\_RX PLANGENERICCOST\_RX

SPECIALTYCOST\_RX PLANSPECIALTYCOST\_RX PERCENT\_HEPC

PLANPERCENT\_HEPC PERCENT\_SPEC PLANPERCENT\_SPEC

PERCENT\_OPIOID PLANPERCENT\_OPIOID)

TIER0DETAIL

TIER1 (KEEP = PRESCRIBERID PRESCRIBERLASTNAME PERCENTSPEND GUR PLANGUR

FORMULARY\_COMPLIANCE PLANFORMULARY\_COMPLIANCE BRANDCOST\_RX

PLANBRANDCOST\_RX GENERICCOST\_RX PLANGENERICCOST\_RX

SPECIALTYCOST\_RX PLANSPECIALTYCOST\_RX PERCENT\_HEPC

PLANPERCENT\_HEPC PERCENT\_SPEC PLANPERCENT\_SPEC

PERCENT\_OPIOID PLANPERCENT\_OPIOID)

TIER1DETAIL

TIER2 (KEEP = PRESCRIBERID PRESCRIBERLASTNAME PERCENTSPEND GUR PLANGUR

FORMULARY\_COMPLIANCE PLANFORMULARY\_COMPLIANCE BRANDCOST\_RX

PLANBRANDCOST\_RX GENERICCOST\_RX PLANGENERICCOST\_RX

SPECIALTYCOST\_RX PLANSPECIALTYCOST\_RX PERCENT\_HEPC

PLANPERCENT\_HEPC PERCENT\_SPEC PLANPERCENT\_SPEC

PERCENT\_OPIOID PLANPERCENT\_OPIOID)

TIER2DETAIL

TIER3 (KEEP = PRESCRIBERID PRESCRIBERLASTNAME PERCENTSPEND GUR PLANGUR

FORMULARY\_COMPLIANCE PLANFORMULARY\_COMPLIANCE BRANDCOST\_RX

PLANBRANDCOST\_RX GENERICCOST\_RX PLANGENERICCOST\_RX

SPECIALTYCOST\_RX PLANSPECIALTYCOST\_RX PERCENT\_HEPC

PLANPERCENT\_HEPC PERCENT\_SPEC PLANPERCENT\_SPEC

PERCENT\_OPIOID PLANPERCENT\_OPIOID)

TIER3DETAIL

TIER4 (KEEP = PRESCRIBERID PRESCRIBERLASTNAME PERCENTSPEND GUR PLANGUR

FORMULARY\_COMPLIANCE PLANFORMULARY\_COMPLIANCE BRANDCOST\_RX

PLANBRANDCOST\_RX GENERICCOST\_RX PLANGENERICCOST\_RX

SPECIALTYCOST\_RX PLANSPECIALTYCOST\_RX PERCENT\_HEPC

PLANPERCENT\_HEPC PERCENT\_SPEC PLANPERCENT\_SPEC

PERCENT\_OPIOID PLANPERCENT\_OPIOID)

TIER4DETAIL

TIER5 (KEEP = PRESCRIBERID PRESCRIBERLASTNAME PERCENTSPEND GUR PLANGUR

FORMULARY\_COMPLIANCE PLANFORMULARY\_COMPLIANCE BRANDCOST\_RX

PLANBRANDCOST\_RX GENERICCOST\_RX PLANGENERICCOST\_RX

SPECIALTYCOST\_RX PLANSPECIALTYCOST\_RX PERCENT\_HEPC

PLANPERCENT\_HEPC PERCENT\_SPEC PLANPERCENT\_SPEC

PERCENT\_OPIOID PLANPERCENT\_OPIOID)

TIER5DETAIL

TIER6 (KEEP = PRESCRIBERID PRESCRIBERLASTNAME PERCENTSPEND GUR PLANGUR

FORMULARY\_COMPLIANCE PLANFORMULARY\_COMPLIANCE BRANDCOST\_RX

PLANBRANDCOST\_RX GENERICCOST\_RX PLANGENERICCOST\_RX

SPECIALTYCOST\_RX PLANSPECIALTYCOST\_RX PERCENT\_HEPC

PLANPERCENT\_HEPC PERCENT\_SPEC PLANPERCENT\_SPEC

PERCENT\_OPIOID PLANPERCENT\_OPIOID)

TIER6DETAIL

TIER7 (KEEP = PRESCRIBERID PRESCRIBERLASTNAME PERCENTSPEND GUR PLANGUR

FORMULARY\_COMPLIANCE PLANFORMULARY\_COMPLIANCE BRANDCOST\_RX

PLANBRANDCOST\_RX GENERICCOST\_RX PLANGENERICCOST\_RX

SPECIALTYCOST\_RX PLANSPECIALTYCOST\_RX PERCENT\_HEPC

PLANPERCENT\_HEPC PERCENT\_SPEC PLANPERCENT\_SPEC

PERCENT\_OPIOID PLANPERCENT\_OPIOID)

TIER7DETAIL

TIER8 (KEEP = PRESCRIBERID PRESCRIBERLASTNAME PERCENTSPEND GUR PLANGUR

FORMULARY\_COMPLIANCE PLANFORMULARY\_COMPLIANCE BRANDCOST\_RX

PLANBRANDCOST\_RX GENERICCOST\_RX PLANGENERICCOST\_RX

SPECIALTYCOST\_RX PLANSPECIALTYCOST\_RX PERCENT\_HEPC

PLANPERCENT\_HEPC PERCENT\_SPEC PLANPERCENT\_SPEC

PERCENT\_OPIOID PLANPERCENT\_OPIOID)

TIER8DETAIL;

SET PLAN6;

\*\*\* CREATE LABELS SO OUTPUT FILE FIELD NAMING CONVENTIONS ARE DESCRIPTIVE \*\*\*;

LABEL PRESCRIBERID = "Prescriber ID"

PRESCRIBERLASTNAME = "Prescriber Last Name"

PERCENTSPEND = "Prescriber Spend Compared to Total Plan"

GUR = "Prescriber Generic Utilization Rate"

PLANGUR = "Plan Generic Utilization Rate"

FORMULARY\_COMPLIANCE = "Prescriber Formulary Compliance"

PLANFORMULARY\_COMPLIANCE = "Plan Formulary Compliance"

BRANDCOST\_RX = "Prescriber Brand Cost Per Rx"

PLANBRANDCOST\_RX = "Plan Brand Cost Per Rx"

GENERICCOST\_RX = "Prescriber Generic Cost Per Rx"

PLANGENERICCOST\_RX = "Plan Generic Cost Per Rx"

SPECIALTYCOST\_RX = "Prescriber Specialty Cost Per Rx"

PLANSPECIALTYCOST\_RX = "Plan Specialty Cost Per Rx"

PERCENT\_HEPC = "Prescriber Percent Hep C Drugs Prescribed"

PLANPERCENT\_HEPC = "Plan Percent Hep C Drugs Prescribed"

PERCENT\_SPEC = "Prescriber Percent Specialty Drugs Prescribed"

PLANPERCENT\_SPEC = "Plan Percent Specialty Drugs Prescribed"

PERCENT\_OPIOID = "Prescriber Percent Opioid Drugs Prescribed"

PLANPERCENT\_OPIOID = "Plan Percent Opioid Drugs Prescribed"

RXCOUNT = "Prescriber Rx Count"

PLANRXCOUNT = "Plan Rx Count"

PAIDAMT = "Prescriber Total Paid"

PLANPAIDAMT = "Plan Total Paid"

FORMULARY\_COUNT = "Prescriber Formulary Rx Count"

PLANFORMULARY\_COUNT = "Plan Formulary Rx Count"

NONFORMULARY\_COUNT = "Prescriber Non-Formulary Rx Count"

PLANNONFORMULARY\_COUNT = "Plan Non-Formulary Rx Count"

BRAND\_COUNT = "Prescriber Brand Rx Count"

PLANBRAND\_COUNT = "Plan Brand Rx Count"

GENERIC\_COUNT = "Prescriber Generic Rx Count"

PLANGENERIC\_COUNT = "Plan Generic Rx Count"

BRAND\_AMT = "Prescriber Brand Amount Paid"

PLANBRAND\_AMT = "Plan Brand Amount Paid"

GENERIC\_AMT = "Prescriber Generic Amount Paid"

PLANGENERIC\_AMT = "Plan Generic Amount Paid"

SPECIALTY\_AMT = "Prescriber Specialty Amount Paid"

PLANSPECIALTY\_AMT = "Plan Specialty Amount Paid"

SPECIALTY\_COUNT = "Prescriber Specialty Rx Count"

PLANSPECIALTY\_COUNT = "Plan Specialty Rx Count"

HEPC\_COUNT = "Prescriber Hep C Rx Count"

PLANHEPC\_COUNT = "Plan Hep C Rx Count"

HEPC\_AMT = "Prescriber Hep C Amount Paid"

PLANHEPC\_AMT = "Plan Hep C Amount Paid"

OPIOID\_COUNT = "Prescriber Opioid Drug Rx Count"

PLANOPIOID\_COUNT = "Plan Opioid Drug Rx Count"

OPIOID\_AMT = "Prescriber Opioid Amount Paid"

PLANOPIOID\_AMT = "Plan Opioid Amount Paid"

WARNING1 = "Warning 1"

WARNING2 = "Warning 2"

WARNING3 = "Warning 3"

WARNING4 = "Warning 4"

WARNING5 = "Warning 5"

WARNING6 = "Warning 6"

WARNING7 = "Warning 7"

WARNING8 = "Warning 8"

BETA = "Beta"

FLAG = "Flag"

TIER = "Tier";

IF TIER = **0** THEN

DO;

OUTPUT TIER0;

OUTPUT TIER0DETAIL;

END;

IF TIER = **1** THEN

DO;

OUTPUT TIER1;

OUTPUT TIER1DETAIL;

END;

ELSE IF TIER = **2** THEN

DO;

OUTPUT TIER2;

OUTPUT TIER2DETAIL;

END;

ELSE IF TIER = **3** THEN

DO;

OUTPUT TIER3;

OUTPUT TIER3DETAIL;

END;

ELSE IF TIER = **4** THEN

DO;

OUTPUT TIER4;

OUTPUT TIER4DETAIL;

END;

ELSE IF TIER = **5** THEN

DO;

OUTPUT TIER5;

OUTPUT TIER5DETAIL;

END;

ELSE IF TIER = **6** THEN

DO;

OUTPUT TIER6;

OUTPUT TIER6DETAIL;

END;

ELSE IF TIER = **7** THEN

DO;

OUTPUT TIER7;

OUTPUT TIER7DETAIL;

END;

ELSE IF TIER = **8** THEN

DO;

OUTPUT TIER8;

OUTPUT TIER8DETAIL;

END;

**RUN**;

Now we need to invoke the PROC SORT procedure to sort by descending PERCENTSPEND, as the higher prescriber percent spend is more important to review. Rather than write code to sort 16 data sets, we create an efficient macro.

\*\*\* CREATE MACRO TO SORT EACH TIER BY DESCENDING PERCENT SPEND \*\*\*;

\*\*\* PERCENT SPEND IS THE PERCENTAGE OF EACH PRESCRIBER'S SPEND TO TOTAL PLAN SPEND \*\*\*;

\*\*\* THIS SORT PROCEDURE ALLOWS RESOURCES TO RESEARCH THE HIGHER TIERS IN ORDER OF \*\*\*;

\*\*\* HIGHEST DOLLAR IMPACT OF PRESCRIBER \*\*\*;

**%MACRO** SortTiers (File= ) ;

PROC SORT DATA=work.&File.;

BY DESCENDING PERCENTSPEND;

RUN;

**%MEND** SortTiers;

%***SortTiers*** (File=Tier0);

%***SortTiers*** (File=Tier1);

%***SortTiers*** (File=Tier2);

%***SortTiers*** (File=Tier3);

%***SortTiers*** (File=Tier4);

%***SortTiers*** (File=Tier5);

%***SortTiers*** (File=Tier6);

%***SortTiers*** (File=Tier7);

%***SortTiers*** (File=Tier8);

%***SortTiers*** (File=Tier0Detail);

%***SortTiers*** (File=Tier1Detail);

%***SortTiers*** (File=Tier2Detail);

%***SortTiers*** (File=Tier3Detail);

%***SortTiers*** (File=Tier4Detail);

%***SortTiers*** (File=Tier5Detail);

%***SortTiers*** (File=Tier6Detail);

%***SortTiers*** (File=Tier7Detail);

%***SortTiers*** (File=Tier8Detail);

The next step is to output the 16 data sets to a MS Excel file and once again, for efficiency and coding time savings we build a macro.

\*\*\* CREATE MACRO TO EXPORT EACH TIER FILE AND EACH TIER DETAIL FILE TO MS EXCEL \*\*\*;

**%MACRO** ExportProfileData (File=, TabName= ) ;

PROC EXPORT DATA=work.&File.

OUTFILE="I:\SAS\Projects\Provider Profile Report.xlsx"

LABEL DBMS=XLSX REPLACE;

SHEET = "&TabName.";

RUN;

**%MEND** ExportProfileData;

%***ExportProfileData*** (File=Tier0, TabName=Tier0);

%***ExportProfileData*** (File=Tier1, TabName=Tier1);

%***ExportProfileData*** (File=Tier2, TabName=Tier2);

%***ExportProfileData*** (File=Tier3, TabName=Tier3);

%***ExportProfileData*** (File=Tier4, TabName=Tier4);

%***ExportProfileData*** (File=Tier5, TabName=Tier5);

%***ExportProfileData*** (File=Tier6, TabName=Tier6);

%***ExportProfileData*** (File=Tier7, TabName=Tier7);

%***ExportProfileData*** (File=Tier8, TabName=Tier8);

%***ExportProfileData*** (File=Tier0Detail, TabName=Tier0Detail);

%***ExportProfileData*** (File=Tier1Detail, TabName=Tier1Detail);

%***ExportProfileData*** (File=Tier2Detail, TabName=Tier2Detail);

%***ExportProfileData*** (File=Tier3Detail, TabName=Tier3Detail);

%***ExportProfileData*** (File=Tier4Detail, TabName=Tier4Detail);

%***ExportProfileData*** (File=Tier5Detail, TabName=Tier5Detail);

%***ExportProfileData*** (File=Tier6Detail, TabName=Tier6Detail);

%***ExportProfileData*** (File=Tier7Detail, TabName=Tier7Detail);

%***ExportProfileData*** (File=Tier8Detail, TabName=Tier8Detail);

The last step we output the Prescriber Profile Report which creates 16 tabs, one streamlined with only the metrics per Tier and one with all detail per Tier.

Below is an example of a TIER 8 prescriber profiling report file, which can be utilized for clinician review.

|  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- |
| Prescriber ID | Prescriber Last Name | Prescriber Formulary Compliance | Plan Formulary Compliance | Prescriber Generic Utilization Rate | Plan Generic Utilization Rate |
| 99999999999 | DOE | 81.82% | 98.13% | 90.48% | 91.88% |

|  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- |
| Prescriber Brand Cost Per Rx | Plan Brand Cost Per Rx | Prescriber Generic Cost Per Rx | Plan Generic Cost Per Rx | Prescriber Specialty Cost Per Rx | Plan Specialty Cost Per Rx |
| $2,198.26 | $400.01 | $71.29 | $15.04 | $12,830.00 | $5,117.96 |

|  |  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- | --- |
| Prescriber Percent Specialty Drugs Prescribed | Plan Percent Specialty Drugs Prescribed | Prescriber Percent Hep C Drugs Prescribed | Plan Percent Hep C Drugs Prescribed | Prescriber Percent Opioid Drugs Prescribed | Plan Percent Opioid Drugs Prescribed | Prescriber Spend Compared to Total Plan |
| 4.55% | 0.42% | 4.55% | 0.02% | 4.55% | 2.62% | 0.13% |

Note in all 8 metrics prescriber Dr. Doe is an outlier and would be a good candidate for review. The distribution of Prescriber spend in this data set goes up to a max of 1.16%, with 99.24% of prescriber spend at 0.13% or lower, so prescriber spend in this instance is not a red flag. Therefore more clinical review time might be better spent at lower Tiers with higher prescriber spend percentages.

Next Steps

I have created the same program which compares member metrics to Plan. Although this is a much larger data set, reviewing the top member outliers using this methodology is an excellent tool, critical to improving patient care and reducing unnecessary cost.

J. Daniel Knapp, MBA

Senior Manager, Pharmacy Informatics, PerformRx

Harvard University, Harvard Extension Finance graduate program student

(856) 759-9990

[DKnapp@PerformRx.com](mailto:DKnapp@PerformRx.com)

[Jdk999@g.harvard.edu](mailto:Jdk999@g.harvard.edu)